<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:template match="CALENDAR[@TYPE='month']">
		<xsl:call-template name="CALENDAR">
			<xsl:with-param name="TopPlaceContent" select="CALENDAR-NAVIGATION"/>
			<xsl:with-param name="MainContent" select="CALENDAR-HEADER|CALENDAR-WEEK"/>
			<xsl:with-param name="BaseUrl" select="@BASE-URL"/>
		</xsl:call-template>
	</xsl:template>
	<xsl:template name="CALENDAR">
		<xsl:param name="TopPlaceContent"/>
		<xsl:param name="MainContent"/>
		<xsl:param name="BottomPlaceContent"/>
		<xsl:param name="BaseUrl"/>
		<table>
			<xsl:apply-templates select="$TopPlaceContent">
				<xsl:with-param name="BaseUrl" select="$BaseUrl"/>
			</xsl:apply-templates>
			<tr>
				<td>
					<table width="100%">
						<xsl:apply-templates select="$MainContent ">
							<xsl:with-param name="BaseUrl" select="$BaseUrl"/>
						</xsl:apply-templates>
					</table>
				</td>
			</tr>
			<xsl:apply-templates select="$BottomPlaceContent">
				<xsl:with-param name="BaseUrl" select="$BaseUrl"/>
			</xsl:apply-templates>
		</table>
	</xsl:template>
	<xsl:template match="CALENDAR-NAVIGATION">
		<xsl:param name="BaseUrl"/>
		<tr>
			<td>
				<table width="100%">
					<tr>
						<xsl:apply-templates select="CALENDAR-NAVIGATION-ITEM[@NAME='PREVIOUS']">
							<xsl:with-param name="BaseUrl" select="$BaseUrl"/>
						</xsl:apply-templates>
						<xsl:apply-templates select="CALENDAR-NAVIGATION-ITEM[@NAME='CURRENT']">
							<xsl:with-param name="BaseUrl" select="$BaseUrl"/>
						</xsl:apply-templates>
						<xsl:apply-templates select="CALENDAR-NAVIGATION-ITEM[@NAME='NEXT']">
							<xsl:with-param name="BaseUrl" select="$BaseUrl"/>
						</xsl:apply-templates>
					</tr>
				</table>
			</td>
		</tr>
	</xsl:template>
	<xsl:template match="CALENDAR-NAVIGATION-ITEM[@NAME!='CURRENT']">
		<xsl:param name="BaseUrl"/>
		<td>
			<xsl:attribute name="style"><xsl:apply-templates select="@NAME"/></xsl:attribute>
			<a>
				<xsl:attribute name="href"><xsl:value-of select="$BaseUrl"/><xsl:value-of select="@CURSOR"/></xsl:attribute>
				<xsl:value-of select="."/>
			</a>
		</td>
	</xsl:template>
	<xsl:template match="CALENDAR-NAVIGATION-ITEM">
		<td>
			<xsl:attribute name="style"><xsl:apply-templates select="@NAME"/></xsl:attribute>
			<xsl:value-of select="."/>
		</td>
	</xsl:template>
	<xsl:template match="CALENDAR-NAVIGATION-ITEM/@NAME[.='CURRENT']">
		<xsl:text>text-align: center;</xsl:text>
	</xsl:template>
	<xsl:template match="CALENDAR-NAVIGATION-ITEM/@NAME[.='PREVIOUS']">
		<xsl:text>text-align: left;</xsl:text>
	</xsl:template>
	<xsl:template match="CALENDAR-NAVIGATION-ITEM/@NAME[.='NEXT']">
		<xsl:text>text-align: right;</xsl:text>
	</xsl:template>
	<xsl:template match="CALENDAR-HEADER">
		<tr>
			<xsl:for-each select="CALENDAR-HEADER-ITEM">
				<td style="font-weight: bold;">
					<xsl:value-of select="."/>
				</td>
			</xsl:for-each>
		</tr>
	</xsl:template>
	<xsl:template match="CALENDAR-WEEK">
		<xsl:param name="BaseUrl" />
		<tr>
			<xsl:apply-templates>
				<xsl:with-param name="$BaseUrl" />
			</xsl:apply-templates>
		</tr>
	</xsl:template>
	<xsl:template match="CALENDAR-POINT/@DISABLED[.!='0']">
		<xsl:text>color: #cccccc;</xsl:text>
	</xsl:template>
	<xsl:template match="CALENDAR-POINT/@SELECTED[.!='0']">
		<xsl:text>background-color: #cccccc;</xsl:text>
	</xsl:template>
	<xsl:template match="CALENDAR-POINT/@CURRENT[.!='0']">
		<xsl:text>color: red;</xsl:text>
	</xsl:template>
	<xsl:template match="CALENDAR-POINT/@*">
	</xsl:template>
	<xsl:template match="CALENDAR-POINT">
		<td>
			<xsl:attribute name="style"><xsl:text>text-align: center;</xsl:text><xsl:apply-templates select="@DISABLED|@SELECTED|@CURRENT"/></xsl:attribute>
			<xsl:value-of select="."/>
		</td>
	</xsl:template>
</xsl:stylesheet>
